Cisco IOSXE

Enable Restconf to use by Terraform

ip http secure-server
restconf
aaa new-model
aaa authentication login default local
aaa authorization exec default local

Sample Configuration to enable Telemetry

• This example uses the followin files:

  • header.tf

  • terraform.tfvars

  • cpu.tf

  • xpaths.tf

  • validate_subscriptions.tf

Header file

• This file defines provider information, including credential and device url

# header.tf
terraform {
  required_providers {
    iosxe = {
      source  = "CiscoDevNet/iosxe"
      version = ">= 0.3.3"
    }
  }
}

provider "iosxe" {
  username = "admin"
  password = "XXXXXXXX"
  url      = "https://your-switch-hostname-or-ip"
}

##########################################
# Should not need to change below here ! #
##########################################
variable source_address {
    type = string
    default = "1.1.1.1"
    description = "Source address" 
}

variable receiver_ip {
    type = string
    default = "1.1.1.1"
    description = "Receiver IP" 
}

variable receiver_port  {
    type = string
    default = "57500"
    description = "Port to send data to" 
}

Variables

# terraform.tfvars
source_address = "10.1.1.5"
receiver_ip = "10.1.1.3"
receiver_port = "57500"
example_periodic = "3000"
cpu_periodic = "3000"

CPU.tf

• file contains the loop that goes through the Subscription ID Numbers and Xpaths from the previous configuratioon file. It also defines some values for the encoding, stream, and update interval defaults.

# CPU.tf
resource "iosxe_mdt_subscription" "cpu_subs" {
  for_each               = var.cpu_subscriptions
  subscription_id        = each.key
  stream                 = "yang-push"
  encoding               = "encode-kvgpb"
  update_policy_periodic = var.cpu_periodic
  source_address         = var.source_address
  filter_xpath           = each.value.xpath
  receivers = [
    {
      address  = var.receiver_ip
      port     = var.receiver_port
      protocol = "grpc-tcp"
    }
  ]
}

variable cpu_periodic {
    type = string
    default = "100"
    description = "Short update interval" 
}

# CPU.tf
variable "cpu_subscriptions" {
  default = {
    100 = {
      xpath = "/process-cpu-ios-xe-oper:cpu-usage/cpu-utilization/five-seconds"
    },
    101 = {
      xpath = "/process-cpu-ios-xe-oper:cpu-usage/cpu-utilization/one-minute"
    },
    102 = {
      xpath = "/process-cpu-ios-xe-oper:cpu-usage/cpu-utilization/five-minutes"
    }
  }
}

XPath

• defines the Xpaths for the environment sensor and the Interfaces Operational data.

resource "iosxe_mdt_subscription" "example" {
  for_each               = var.subscriptions
  subscription_id        = each.key
  stream                 = "yang-push"
  encoding               = "encode-kvgpb"
  update_policy_periodic = var.example_periodic
  source_address         = var.source_address
  filter_xpath           = each.value.xpath
  receivers = [
    {
      address  = var.receiver_ip
      port     = var.receiver_port
      protocol = "grpc-tcp"
    }
  ]
 }

variable example_periodic {
    type = string
    default = "6000"
    description = "Long update interval" 
}

# XPATH.tf
variable "subscriptions" {
  default = {
    103 = {
      xpath = "/environment-ios-xe-oper:environment-sensors"
    },
    104 = {
      xpath = "/interfaces-ios-xe-oper:interfaces"

    }
  }
}

Validation

• confirms that all the subscriptions were properly created from the previous files using the mdt data_source.

# validate_subscriptions.tf
data "iosxe_mdt_subscription" "example100" {
  subscription_id = 100
}

data "iosxe_mdt_subscription" "example101" {
  subscription_id = 101
}

data "iosxe_mdt_subscription" "example102" {
  subscription_id = 102
}

data "iosxe_mdt_subscription" "example103" {
  subscription_id = 103
}

data "iosxe_mdt_subscription" "example104" {
  subscription_id = 104
}

Run Terraform

• terraform init

• terraform plan

  • if the .tfvars file is NOT named terraform.tfvars, it can be explicitly defined which variable file to use with this format terraform plan -var-file="var.tfvars"

• terraform apply

  • if the .tfvars file is NOT named terraform.tfvars, it can be explicitly defined which variable file to use with this format terraform apply -var-file="var.tfvars"

• terraform destroy

resource "iosxe_cli" "example" {
    cli = <<-EOT
    interface loopback123
    description configured-via-restconf-cli
    EOT
}

Resource

• https://github.com/CiscoDevNet/terraform-provider-iosxe

• https://registry.terraform.io/providers/CiscoDevNet/iosxe/latest

• Automate Cisco IOS XE Device Configuration Using Terraform - DEVLIT-2083

• An automated Ansible to Terraform translation for ACI - DEVLIT-2829

• Introduction to Infrastructure as Code for Cisco Catalyst Center with Terraform - BRKOPS-1183

• https://github.com/pamosima/BRKOPS-1183_TF-Demo

• Terraform: ThousandEyes on Catalyst 9000 Switches - DEVNET-1458

• Self-Service Automation for your DC Network using Ansible, Terraform and ServiceNow. - DEVNET-1892

• How to Become a Cisco IOS XE Terraform Expert - DEVNET-2464

• Automating cloud networking with Cloud Network Controller and Terraform - DEVNET-2280